#include "colors.inc" 
#include "woods.inc"


/*camera{
	orthographic 
	location <50,50,100>
	look_at <0,0,0> 
	angle 80
	}

background{color Gray90}



light_source{<50,190,100> color White}   
*/


//Tous les éléments de la chaise sont construits avec des objets CSG   
   
      
      
      
// Création des pieds qui supportent le dossier
// Les pieds de la chaise sont crées comme ceux de la table : un cylindre auquel on retire des torus pour faire des motifs 
#declare pied1= 
    union {
       difference {
         cylinder {<0,60,0> <0,-30,0> 3}
         torus {3,1 translate -20*y} 
         torus {3,1 translate 6*y} 
         torus {3,1 translate 0*y} 
         torus {3,1 translate 22*y} 
         torus {3,1 translate 28*y}
         torus {3,1 translate 59*y} 
      } 
      torus {2,1 translate -30*y}
      sphere {<0,63,0> 3.5}     
      texture {T_Wood14 scale 80 } 
    }
    




// Création des autres pieds    
#declare pied2= 
    difference {
        object{pied1}
        box{<-6,16,-6>,<6,70,6>}
        texture {T_Wood14 scale 80 }  
         } 
    
    
    
  
    
// Création de l'assise    
#declare siege=
        union{
           difference{
               box{<1,10,0>,<-40,15,40>}
               box{<-2,8,3>,<-37,17,37> } 
               texture {T_Wood14 scale 80 } 
                        }
           box {<-4,10,5>,<-35,16,35>}
           cylinder {<-4,13,5> <-35,13,5> 3}
           cylinder {<-4,13,35> <-35,13,35> 3}
           cylinder {<-35,13,5> <-35,13,35> 3} 
           cylinder {<-4,13,5> <-4,13,35> 3}
           sphere {<-4,13,5> 3}
           sphere {<-35,13,5> 3}
           sphere {<-4,13,35> 3}
           sphere {<-35,13,35> 3}
           texture {T_Wood13 scale 50}        
                        }



// Création du dossier
// Le dossier est crée à partir de sphères pour donner la forme arrondie 
#declare dossier=
        difference{
                sphere {<-20,40,22> 31} 
                sphere {<-20,40,22> 29}
                box {<30,50,60> <-60,75,-30>} 
                box {<30,0,60> <-60,70,1>}
                box {<30,35,60> <-60,40,-30>}  
                box {<30,0,60> <-60,30,-30>}
                texture {T_Wood14 scale 80 }
                }




// Assemblage de la chaise
#declare chaise=
     union{
        object {pied1 finish{phong 1 diffuse 0.6 reflection 0.1 ambient 0.4 }}
        object {pied1 translate -40*x finish{phong 1 diffuse 0.6 reflection 0.1 ambient 0.4 }}
        object {pied2 translate 40*z finish{phong 1 diffuse 0.6 reflection 0.1 ambient 0.4 }} 
        object {pied2 translate <-40,0,40> finish{phong 1 diffuse 0.6 reflection 0.1 ambient 0.4 }} 
        object{siege}
        object{dossier translate 4*y finish{phong 1 diffuse 0.6 reflection 0.1 ambient 0.4 }}
        
             
    // Les cylindres suivants correspondent aux barreaux qui relient les pieds de la chaise   
        cylinder {<0,-12,0> <0,-12,40> 1.5 texture {T_Wood14 scale 80 } finish{phong 1 diffuse 0.6 reflection 0.1 ambient 0.4 }}
        cylinder {<-40,-14,0> <-40,-14,40> 1.5 texture {T_Wood14 scale 80 } finish{phong 1 diffuse 0.6 reflection 0.1 ambient 0.4 }}
        cylinder {<0,-8,0> <-40,-8,0> 1.5 texture {T_Wood14 scale 80 } finish{phong 1 diffuse 0.6 reflection 0.1 ambient 0.4 }}
        cylinder {<0,-8,40> <-40,-8,40> 1.5 texture {T_Wood14 scale 80 } finish{phong 1 diffuse 0.6 reflection 0.1 ambient 0.4 }} 


 }
 
 
//object{chaise}